Polarization of an Optical Wave through Polarizers and Wave Plates

Manipulate[
If[JvC ==1,init=True,init=False];
If[JmC ==1,polarize=True,{polarize=False;βdeg = 0}];
α=π αdeg /180.;
β=π βdeg /180.;
E1 = Evaluate[E0*Jv];
Jv = Piecewise[{{JvLinear[α],JvC == 1},{JvRCircular,JvC == 2},{JvLCircular,JvC == 3}}];
Jm = Piecewise[{{JmLinear[β],JmC == 1},{JmQWP,JmC == 2},{JmHWP, JmC == 3}}];
E2 = Evaluate[Jm.E1];
p1 = ParametricPlot3D[Re[Insert[E1,x,1]]/. x-> x1 /. t-> (t1),{x1,0,4Pi-.4},Axes->False,PlotRange->{{0,8Pi},{-2,2},{-2,2}},Boxed->False,ImageSize->{280,375},ViewVector-> {Insert[ϕ,20Pi,1],{0,0,0}},ImageSize->{280,375}];
p2 = ParametricPlot3D[Re[Insert[E2,x,1]] /. x-> x1 /. t-> (t1), {x1,4Pi+.4,8Pi}];
p3 = Graphics3D[{Black,Thick, Line[{{0,0,0},{8Pi,0,0}}],
Line[{{0,0,0},{0,-2,0}}],
Line[{{0,0,0},{0,0,2}}],
Polygon[{{0,0,2},{0,.1,1.8},{0,-.1,1.8}}],
Polygon[{{0,-2,0},{0,-1.8,.1},{0,-1.8,-.1}}],
Polygon[{{8Pi,0,0},{8Pi-1,.1,0},{8Pi-1,-.1,0}}],
Black,Rotate[Line[{{4π,1,0},{4π,-1,0}}],β,{1,0,0}],
Black,GrayLevel[.5,.5],Rotate[Cuboid[{4Pi-.4,-1,-1},{4Pi+.4,1,1}],β,{1,0,0}]}];
coords = Re[Insert[E2,8Pi,1]/. x-> 8Pi /. t-> (t1)];
p4 = Graphics3D[{Yellow,Thick,Line[{{8Pi,0,0},coords}]}];
p5 = ParametricPlot3D[Re[Insert[E2,8Pi,1]] /. x-> x1 /. t-> (t1), {x1,4Pi+.4,8Pi},PlotStyle->Purple];
Show[p1,p2,p3,p5,p4,ImageSize->{375,375}],
{{t1,0,"animation"},0,2Pi,
ControlType->Animator,
AppearanceElements->{"PlayPauseButton","FasterSlowerButtons","ProgressSlider"},
AnimationRate->.3,
AnimationRunning->False,ImageSize->Small,
ControlPlacement->Top},
{{JvC,1,"initial wave"},
{1->"linear",
2-> "right circular",
3->"left circular"},
ControlType->PopupMenu,
ControlPlacement->Left},
{{αdeg,45.,"initial angle"},0,360.,ControlPlacement->Left,Enabled->Dynamic[init],ImageSize->Small},
{{JmC,1,"optical element"},
{1->"linear polarizer",
2->"quarter-wave plate",
3->"half-wave plate"},
ControlType->PopupMenu,
ControlPlacement->Left},
{{βdeg,0,"polarizer angle"},0,360.,ControlPlacement->Left,Enabled->Dynamic[polarize],ImageSize->Small},
{{ϕ,{-10,10},"view point"},{-10,-10},{10,10},ControlType->Slider2D,ControlPlacement->Left},
TrackedSymbols->Manipulate,
Initialization:> {
E0 = {E^(I(k x - ω t)),E^(I(k x - ω t))}/. k->1 /. ω -> 1;
JvLinear [α_] := {Cos[α],Sin[α]};
JvRCircular = 1/Sqrt[2] {1,-I};
JvLCircular = 1/Sqrt[2] {1,I};
JmLinear[β_] := {{Cos[β]^2,Sin[β] Cos[β]},{Sin[β] Cos[β],Sin[β]^2}};
JmQWP = E^-(I Pi/4){{1,0},{0,I}};
JmHWP = E^-(I Pi/2){{1,0},{0,-1}};
Jv = JvLinear[Pi/4];
Jm = JmLinear[0]},AutorunSequencing->{1,4,5,6}]

CAPTION

Wave plates and linear polarizers are common optical elements that alter the polarization of light passing through them. This Demonstration shows the effect of the optical element on the polarization of light. You can select the optical element from the drop-down menu and set the polarization state of the incident wave (linear, right circular, or left circular). The line through the optical element represents the direction of polarization (transmission axis) for the polarizer and the fast axis for half- and quarter-wave plates.

DETAILS

An electromagnetic (EM) wave propagating in the z direction can be represented mathematically as

E =(({{(Subscript[E, 0x])(e^(δx)) }, {(Subscript[E, 0y])(e^(δy)) }}))(e^(i (k z-ω t))),

where (Subscript[E, 0x]) and (Subscript[E, 0y]) are the amplitudes of the x and y components of the electric field, k is the wave number, z is the distance along the propagation direction, ω is the frequency, t is the time, and δ is the phase. The term in brackets is referred to as the Jones vector, which gives the polarization of the wave; for example:

(Subscript[E, 0])=(({{cos(α)}, {sin(α)}})), linearly polarized light angle α from the x axis,

(Subscript[E, 0])=(1/(Sqrt[2]))(({{1}, {±i}})), left/right circularly polarized light,

(Subscript[E, 0])=(1/(Sqrt[(A^2)+(B^2)+(C^2)]))(({{A}, {B+i C}})), elliptically polarized light.

Optical elements that modify polarization are made from anisotropic materials. In an anisotropic material the index of refraction is different for the vertical and horizontal components of the optical wave. For example, quarter-wave plates are typically made from calcite, which is birefringent, and linear polarizers can be made from Polaroid sheets, which are dichroic. Once light passes through these materials, the polarization of the transmitted light changes. Depending on the material and orientation of the incident light, the transmitted light can be linearly or circularly polarized, both of which are special cases of elliptical polarization.

In this Demonstration, we assume the light source was polarized at some point before reaching the origin. Once the light comes into contact with an anisotropic optical element it will go through a change in polarization calculated by using the appropriate Jones matrix. You can choose between three common optical components: a linear polarizer, a quarter-wave plate and a half-wave plate.

Snapshot 1: When a wave comes into contact with a linear polarizer only the components parallel to the transmission angle of the polarizer are transmitted. This also causes it to have a lower amplitude than the incident wave, unless the polarizer and incident wave are polarized in the same direction. The Jones matrix for a linear polarizer with transmission axis oriented at an angle β with the x axis is

M= (({{(cos^2)(β), sin(β) cos(β)}, {sin(β) cos(β), (sin^2)(β)}})).

Snapshot 2: When a quarter-wave plate is used, the x and y components of the electric field become 90° or 180° out of phase, respectively. If the incident wave is linearly polarized, the resulting wave is elliptically polarized. Notice that the tip of the electric field vector traces out an ellipse (shown in purple). The Jones matrix for a quarter waveplate is

M=(e^(-(i (π/4)))) (({{1, 0}, {0, i}})).

Snapshot 3: Linearly polarized light incident on the quarter-wave plate at 45° results in equal x and y components. In this case the transmitted light is circularly polarized, a special case of elliptical polarization.

Snapshot 4: Linearly polarized light incident on a half-wave plate will be rotated.

Suggestion: use a quarter-wave plate and a half-wave plate with circularly polarized incident light and see the results.

Reference:

F. L. Pedrotti and L. S. Pedrotti, Introduction to Optics, 2nd ed., Upper Saddle River, NJ: Prentice Hall, 1993.

THIS NOTEBOOK IS THE SOURCE CODE FROM

"Polarization of an Optical Wave through Polarizers and Wave Plates" from the Wolfram Demonstrations Project
 http://demonstrations.wolfram.com/PolarizationOfAnOpticalWaveThroughPolarizersAndWavePlates/

Contributed by: Fred E. Moolekamp and Kevin L. Stokes (University of New Orleans)

A full-function Wolfram Mathematica system (Version 6 or higher) is required to edit this notebook.
GET WOLFRAM MATHEMATICA »

© Wolfram Demonstrations Project & Contributors   |   Terms of Use   |   Make a new version of this Demonstration »