Optical Rotation and Ellipticity

Manipulate[
orplot[kdiff,loss,t],
{{kdiff,1.07,"ratio of wave vectors"},1,1.1, Appearance->"Labeled"}, 
{{loss,30,"absorption of one\ncircular component (%)"},0,100,Appearance->"Labeled"},
{{t,0,"time"},0,2 Pi - Pi/16,Pi/16,ControlType->Animator,AnimationRunning->False},

(* Below we define all the components for this simulation *)
Initialization :> (
blue := RGBColor[0.392193,0.584307,0.929395];
red:=RGBColor[0.829997,0.239998,0.099994];
green :=RGBColor[0.380001,0.700003,0.159993];
 ω:=3; (* frequency *)
amp := 3; (* amplitude of the individual waves *)
len := 12 Pi ; (* length of the "cuvette" *)
pos2 := len + 7 Pi ;(* position of "detector" *)
k1[s_] := 1;  (* k-value for the first wave *)
k2[s_,kdiff_] := If[ s < 0  || s > len,k1[0], k1[0] * kdiff]; (* k-value for the second wave relative to that of the first one *)
Δ[s_,kdiff_] := If[s < len, 0, k1[0] * kdiff * len];(* additional phase shift after the wave has passed through the medium*)
a1[s_] = amp;
(* next line: we have a bit of absorption going on for the second set of waves, too. More realistically we should apply Beer's law here but I wanted to keep things simple so it's 
a LINEAR function instead of an exponential function *)
a2[s_,loss_] := If[s < 0,amp,If[s ≥ 0 && s ≤ len, amp (1-  (loss/100) s/len),amp (1 - loss/100)]];
w11[t_,s_,ϕ_] := a1[s] Sin[ (ϕ +k1[s] s) -ω t];
w22[t_,s_] := a1[s] Sin[(k1[s] s ) -ω t];
v11[t_,s_,ϕ_,kdiff_,loss_] := a2[s,loss]  Sin[ (ϕ + Δ[s,kdiff]+k2[s,kdiff ]s ) -ω t];
v22[t_,s_,kdiff_,loss_] := a2[s,loss]  Sin[( Δ[s,kdiff] +k2[s,kdiff ]  s) -ω t];
xx := 2 amp;
box=Show[
Graphics3D[{AbsoluteThickness[2],Line[{{-xx,len,-xx},{-xx,len,xx},{xx,len,xx},{xx,len,-xx},{-xx,len,-xx}}]}],
Graphics3D[{AbsoluteThickness[2],Line[{{-xx,0,-xx},{-xx,0,xx},{xx,0,xx},{xx,0,-xx},{-xx,0,-xx}}]}],
Graphics3D[{AbsoluteThickness[2],Line[{{-xx,0,-xx},{-xx,len,-xx}}]}],
Graphics3D[{AbsoluteThickness[2],Line[{{xx,0,xx},{xx,len,xx}}]}],
Graphics3D[{AbsoluteThickness[2],Line[{{-xx,0,xx},{-xx,len,xx}}]}],
Graphics3D[{AbsoluteThickness[2],Line[{{xx,0,-xx},{xx,len,-xx}}]}]
];

(* Next; we create the superposition of two circularly polarized waves,  with opposite helicity (use phase shifts of Pi/2 and -Pi/2 for the linear components)  *) waveSup[t_,s_,kdiff_,loss_] :=  { v22[t,s,kdiff,loss] + w22[t,s] , s,v11[t,s,Pi/2,kdiff,loss] + w11[t,s,-Pi/2]  };

(* next, we define the actual appearence of the plot *)
orplot[kdiff_,loss_,t_] := Module[ {s,t2},
Show[ParametricPlot3D[
waveSup[t,s,kdiff,loss],
{s,-5 Pi,len + 5  Pi },Boxed->False,Axes-> False, PlotStyle->{blue,AbsoluteThickness[3.]}],
 box,

Graphics3D[{green,AbsoluteThickness[3.],Line[{{0,pos2,0},
    waveSup[t,pos2,kdiff,loss]                  }]}], (* the field vector at s = pos *)

ParametricPlot3D[
waveSup[t2,pos2,kdiff,loss],
{t2,0,2Pi },Boxed->False,Axes-> False,PlotStyle->{Black,AbsoluteThickness[1.]}],(* the projection of the outgoing wave at the "detector" *) 

 PlotRange->All,ImageSize->{450,350}]
];  (* The definition for the plot that we are going to do (the static part depending on parameters t, kdiff, and the loss) *)
), SaveDefinitions->True]

CAPTION

Circularly polarized light waves (or, in general, electromagnetic waves) can be constructed as a superposition of two linearly polarized light waves of the same frequency with perpendicular planes of polarization, equal amplitudes, and a phase shift of one quarter of a wavelength. Depending on the sign of the phase shift the resulting wave is a left- or right-hand circularly polarized wave.

In turn, a linearly polarized light wave can be constructed from a superposition of a left- and a right-hand circularly polarized wave. The plane of polarization depends on the phase shift between the two circularly polarized components. We can use this behavior to explain the phenomenon of optical rotation. Consider a medium, indicated  in the animation by the rectangular box, that is chiral. For example, in chemistry one has a solution of a chiral compound with some enantiomeric excess. The medium interacts slightly differently with the left- and the right-hand circular components of a linearly polarized light wave. (The electric field vector goes around on a left- or right-handed helix that can also be considered chiral.) These different interactions cause the refractive indices for the circular components to be slightly different, slowing down one of the circular components more than the other as they enter the medium. As the linearly polarized wave passes through the medium, the phase shift increases between the two circular components, which manifests in a rotation of the plane of polarization of their superposition.

The animation is constructed in exactly this way. The electric field vector for the incoming linearly polarized wave, in blue, is constructed as a superposition of left- and right-hand circularly polarized components. You can adjust the ratio of the wave vectors for the left- and right-hand circular components. The more the ratio deviates from unity, the larger the optical rotation angle becomes. As you can see, the rotation angle is also proportional to the path length that the light wave takes through the chiral medium. There is a symbolic "detector" that traces the amplitude of the outgoing wave at a fixed position.

If the chiral medium also absorbs light, then the amplitude ratio of the two circularly polarized components changes, in addition to the change in their relative phase. The medium exhibits circular dichroism, that is, the absorption coefficients for the circular components are slightly different. A percentage absorption can be selected in the animation for one of the circularly polarized components relative to the other over the full path length. For simplicity, the animation is constructed such that the first component is not absorbed at all. Also, the Demonstration assumes that a simple linear decrease of the amplitude has been applied instead of the exponential decrease according to Beer's law. The result is an outgoing wave that not only has its plane of polarization rotated but is also elliptically polarized. In the case of 100% absorption you can see the single remaining circularly polarized component. The amount of ellipticity, which is proportional to the medium's circular dichroism, is also shown by the detector.

The animation, qualitatively, models what goes on inside a polarimeter. Note that the dimensions (wavelengths versus cuvette size, etc.) are not to scale! We suggest pausing the animation between rotations because it is quite CPU intensive.

DETAILS

See the author's web page for more information on this subject.

THIS NOTEBOOK IS THE SOURCE CODE FROM

"Optical Rotation and Ellipticity" from the Wolfram Demonstrations Project
 http://demonstrations.wolfram.com/OpticalRotationAndEllipticity/

Contributed by: Jochen Autschbach

A full-function Wolfram Mathematica system (Version 6 or higher) is required to edit this notebook.
GET WOLFRAM MATHEMATICA »

© Wolfram Demonstrations Project & Contributors   |   Terms of Use   |   Make a new version of this Demonstration »