Motion Parallax versus Depth, 3D (Visual Depth Perception 13)

Manipulate[
Module[{degrees,f,i,Δ,c,n,r,dα,point,curve,valueθ,valueα},
degrees[q_]:=q*180/π;
f[Δ_]=((Δ i/c-n r(1+Δ))/(1+Δ));
dα[Δ_]=degrees[c (1+(1/Δ))];
point[Δ_]={f[Δ],dα[Δ],Δ};
c=π/180.;
r=13/10;i=13/2;n=1/2;

curve=ParametricPlot3D[point[Δ],{Δ,.01,1},PlotStyle->{AbsoluteThickness[2],Red},BoxRatios->{1,1,1},AxesLabel->{Style["f",Italic],HoldForm[d α/(d t)],Style["d",Italic]/Style["f",Italic]},PlotRange->{{-.2,200},{-.1,14},{-.01,1}}];
valueθ=Graphics3D[{Red,Text[Row[{HoldForm[d θ/(d t)], " = ",Round[degrees[(((depth f[depth]) i)/((depth+1)f[depth] (f[depth]+n r)))],.01]}],point[depth]+{0,0,.1}]}];
valueα=Graphics3D[{Blue,AbsolutePointSize[4],{Point[point[depth]],Line[{{0,0,0},{0,0,depth},{0,dα[depth],depth},point[depth],{f[depth],dα[depth],0},{f[depth],0,0},{f[depth],0,depth},point[depth]}],
Line[{{f[depth],0,depth},{0,0,depth},{0,0,0},{0,dα[depth],0},{0,dα[depth],depth}}],Line[{{0,0,0},{f[depth],0,0}}],Line[{{0,dα[depth],0},{f[depth],dα[depth],0}}],
Text[Row[{Style["f",Italic]," = ",Round[f[depth],.02]}],{f[depth]/2,dα[depth],depth+.05}],
Text[Row[{Style["d",Italic]/Style["f",Italic]," = ",Round[depth,.02]}],{f[depth]-20,dα[depth],depth/2}],
Text[Row[{HoldForm[d α/(d t)]," = ",Round[dα[depth],.02]}],{f[depth]+20,dα[depth]/2,depth}]}}];

Show[{curve,valueθ,valueα},ImageSize->{400,400}]]
,{{depth,.5,"relative depth"},.1,1,Appearance->"Labeled"}]

CAPTION

This Demonstration lets you move the relative distance between 0 and 1 and uses the formulas below to find the fixate distance f and pursuit rate d α/d t, keeping the motion d θ/d t=1°.

DETAILS

The retinal motion of a distractor viewed by a translating observer is not sufficient by itself to determine the relative depth of an object. This is similar to the static situation where binocular disparity does not determine depth by itself, but together with convergence does determine it.

The Demonstration "Motion Parallax versus Depth, 2D (Visual Depth Perception 12)" (see Related Links) shows both fixate distance and pursuit on separate graphs. There are additional details in that Demonstration. This Demonstration shows both the fixate distance and associated pursuit rate on a single 3D curve where retinal motion is constant.

The Demonstration "The Motion/Pursuit Law in 1D" (see Related Links) shows how the ratio of motion to pursuit does determine relative depth in this basic case.

THIS NOTEBOOK IS THE SOURCE CODE FROM

"Motion Parallax versus Depth, 3D (Visual Depth Perception 13)" from the Wolfram Demonstrations Project
 http://demonstrations.wolfram.com/MotionParallaxVersusDepth3DVisualDepthPerception13/

Contributed by: Keith Stroyan

A full-function Wolfram Mathematica system (Version 6 or higher) is required to edit this notebook.
GET WOLFRAM MATHEMATICA »

© Wolfram Demonstrations Project & Contributors   |   Terms of Use   |   Make a new version of this Demonstration »