Circular and Elliptic Polarization of Light Waves

Manipulate[
waveplot[a, ϕ, t, components], 
 {{t, 0, "time"}, 0, 2*Pi - Pi/16, Pi/16, ControlType -> Animator,AnimationRunning->False},
{{a, 1, "amplitude ratio"}, 0.5, 2, Appearance -> "Labeled"}, 
{{ϕ, Pi/2, "phase shift ϕ"}, 0, Pi, Appearance -> "Labeled"}, 
{{components, False, "show components"}, {True, False}}, 
Initialization :>
(blue = RGBColor[0.392193, 0.584307, 0.929395];
red = RGBColor[0.829997, 0.239998, 0.099994];
green = RGBColor[0.380001, 0.700003, 0.159993];
orange=Orange;
ω = 3;
w1[a_, t_, s_, ϕ_] := 4*Sqrt[a]*Sin[ (s + ϕ) - ω*t];
w2[a_, t_, s_] := (4/Sqrt[a])*Sin[s - ω*t ]; 
v1[a_, t_, s_, ϕ_] := {0, s, w1[a, t, s, ϕ]};
v2[a_, t_, s_, ϕ_] := {w2[a, t, s], s, 0};
v3[a_, t_, s_, ϕ_] :={w2[a, t, s], s, w1[a, t, s, ϕ]};
waveplot[a_, ϕ_, t_, components_] := Module[{s, t2},
Show[
If[components, 
ParametricPlot3D[{v1[a, t, s, ϕ],v2[a, t, s, ϕ], v3[a, t, s, ϕ]}, {s, 0, 10*Pi},Boxed -> False, Ticks -> {None, {{0, "0π"}, 2*Pi, 4*Pi,6*Pi, 8*Pi, 10*Pi}, None},PlotStyle -> {{blue, AbsoluteThickness[2.]},{red, AbsoluteThickness[2.]}, {green, AbsoluteThickness[3.]}, {orange, AbsoluteThickness[3.]}}, Method -> {Compiled -> False}],
ParametricPlot3D[{v3[a, t, s, ϕ]}, {s, 0, 10*Pi}, Boxed -> False,Ticks -> {None, {{0, "0π"}, 2*Pi, 4*Pi, 6*Pi, 8*Pi,10*Pi}, None}, PlotStyle ->{green, AbsoluteThickness[3.]}], Method ->{Compiled -> False}], 
Graphics3D[{green, AbsoluteThickness[3.], 
Line[{{0, pos, 0},{w2[a, t, pos], pos, w1[a, t, pos, ϕ]}}]}],ParametricPlot3D[{w2[a, t2, pos], pos, w1[a, t2, pos, ϕ]},{t2, 0, 2*Pi},PlotStyle -> {Black, AbsoluteThickness[1.]},PlotRange -> All, Method -> {Compiled -> False}],PlotRange -> All,ImageSize->{500,400}]];
pos= 12*Pi; )]

CAPTION

A superposition of two linearly polarized light waves with perpendicular polarization planes results in a linear, elliptical, or circular polarized wave, depending on the amplitudes and the phase shift between the two waves.

In the animation the electric field components of the two individual waves are shown in red and blue if "show components" is selected. The electric field component of the resulting superposition is shown in green. If the superimposed waves have equal amplitude and a phase shift of a quarter wavelength (π/2), the resulting wave has circular polarization. This is the default setting for the animation. If the phase shift is not equal to π/2, or if the waves have different amplitudes, the superposition wave has elliptic polarization. Adjust "amplitude ratio" or "phase shift" to see the effect. A "detector" at position 12 π traces the amplitude of the resulting wave and shows the polarization. The animation can be freely rotated. Select a phase shift of zero or 2 π to obtain a superposition wave with linear polarization.

THIS NOTEBOOK IS THE SOURCE CODE FROM

"Circular and Elliptic Polarization of Light Waves" from the Wolfram Demonstrations Project
 http://demonstrations.wolfram.com/CircularAndEllipticPolarizationOfLightWaves/

Contributed by: Jochen Autschbach

A full-function Wolfram Mathematica system (Version 6 or higher) is required to edit this notebook.
GET WOLFRAM MATHEMATICA »

© Wolfram Demonstrations Project & Contributors   |   Terms of Use   |   Make a new version of this Demonstration »