Laser Lineshape and Frequency Fluctuations: Low-Pass Filtered White Noise

fourierSpectrum[list_List,SampRate_?NumberQ]:= Module[{flist},
    flist=Abs[Take[Fourier[list],{1,IntegerPart[Length[list]/2]+1}]]Sqrt[2./Length[list]];
    Transpose[{Table[(n-1)SampRate/2./(Length[flist]-1),{n,Length[flist]}],flist}]]

Manipulate[
Quiet@Module[{h0,fc,Npts,sr,τlist,RElist,SElist,amp0,lf,FWHM},
h0=(10^logh0);
fc=(10^logfc);
Npts=50;
sr=0.5 Min[Npts (((h0 fc))^0.5),Npts h0];
τlist=Table[i/sr,{i,-Npts,Npts}];
RElist=(E^(-2 h0 (-(((Sin[fc π Abs[#]])^2)/fc)+π Abs[#] SinIntegral[2 fc π Abs[#]])))&/@τlist;
SElist=fourierSpectrum[RElist,sr];
amp0=Max[Transpose[SElist][[2]]];
SElist={#[[1]],(amp0^(-1))#[[2]]}&/@SElist;
lf=Interpolation[SElist];
FWHM=2 x/.(FindRoot[lf[x]-0.5,{x,0.001,Max[First/@SElist]}]);
Grid[{
{LogLogPlot[{Piecewise[{{h0,f≤fc}},(10^(-9))],((8 Log[2])/(π^2))f} ,{f,0.1,1001},
Filling->{1->Bottom},Exclusions->None,PlotStyle->{Automatic,{Red,Dashed}},
Frame->True,FrameLabel->{"(Subscript[f, ])  [Hz]","(Subscript[S, δν])((Subscript[f, ]))  [(Hz^2)/Hz]","frequency noise spectral density"},
GridLinesStyle->LightGray,GridLines->Automatic,
	PlotRange->{{0.1,1000},{0.1,1000}},BaseStyle->12,ImageSize->300],
SpanFromLeft},
{ListLinePlot[Transpose[{τlist,RElist}],
	Axes->False,Frame->True,Filling->Bottom,FrameLabel->{"τ [s]","(Subscript[R, E])(τ)","autocorrelation function"},
	FrameTicks->{Automatic,None},PlotRange->{All,{0,1}},BaseStyle->14,ImageSize->275,
	ImagePadding->40,GridLinesStyle->LightGray,GridLines->{{},{0.5}}],
ListLinePlot[Join[Reverse[{-#[[1]],#[[2]]}&/@SElist],SElist],
	Axes->False,Frame->True,Filling->Bottom,FrameLabel->{"ν-(Subscript[ν, 0]) [Hz]","(Subscript[S, E])(ν-(Subscript[ν, 0]))","laser lineshape"},
	FrameTicks->{Automatic,None},PlotRange->{All,{0,1}},BaseStyle->14,ImageSize->275,
	ImagePadding->40,GridLinesStyle->LightGray,GridLines->{{},{0.5}},Epilog->{Arrow[{{-1.5FWHM,0.5},{-0.5FWHM,0.5}}],Arrow[{{1.5FWHM,0.5},{0.5FWHM,0.5}}],Text[ToString[NumberForm[FWHM,2]]<>" Hz",{FWHM,0.5},{-1,-1}]}]}
},Alignment->{Center,Baseline}]
],
{{logh0,1,"frequency noise level (log scale)"},Log[10,0.2],Log[10,500]},
{{logfc,2,"cutoff frequency (log scale)"},Log[10,0.2],Log[10,500]},
SaveDefinitions->True]

Caption

Frequency fluctuations cause the optical field of a real laser to deviate from a pure sine wave. Thus the laser is not purely monochromatic, its power spectrum showing a broadened lineshape rather than a Dirac delta function. The lineshape and linewidth depend on the spectral properties of the frequency fluctuations. This Demonstration calculates the lineshape of a laser having a constant frequency noise level (Subscript[h, 0]) below a cutoff frequency (Subscript[f, c]) but zero above this threshold. When (Subscript[f, c]) ≪ (Subscript[h, 0]), the lineshape is Gaussian and the linewidth increases as (Sqrt[(Subscript[h, 0]) (Subscript[f, c])]). When (Subscript[f, c])≪(Subscript[h, 0]), the lineshape becomes Lorentzian and the linewidth is independent of (Subscript[f, c]). These observations lead us to separate the frequency noise spectrum into two regions where the effect of noise on the lineshape is radically different: 1) the slow modulation area (left side of the red line) where the noise contributes to the laser linewidth, with a Gaussian shape, and 2) the fast modulation area (right side of the red line) where the noise contributes only to the wings of the line, and not to the linewidth, thus transforming the lineshape from Gaussian to Lorentzian.

Details

The calculation of the laser lineshape (Subscript[S, E])(ν-(Subscript[ν, 0])) from the frequency noise spectral density (Subscript[S, δν])(f) is described in D. S. Elliott, R. Roy, and S. J. Smith, "Extracavity Laser Band-Shape and Bandwidth Modification," Phys. Rev. A 26, 1982 pp. 12–18. First, one calculates the autocorrelation function of the optical field:

(Subscript[R, E])(τ)=(OverBar[E(t)(SuperStar[E])(t+τ)])=(((Subscript[E, 0])^2)/4)exp(-2(∫_0^∞)(Subscript[S, δν])[f](((sin(π f τ))^2)/(f^2))df).

Then the lineshape is given by the Fourier transform of the autocorrelation function:

(Subscript[S, E])(ν-(Subscript[ν, 0]))=(∫_0^∞)cos(2π(ν-(Subscript[ν, 0]))τ) (Subscript[R, E])(τ)dτ.

In the case of a low-pass filtered white noise, that is, for a frequency noise spectral density given by

(Subscript[S, δν])(f)=(Piecewise[{{(Subscript[h, 0]), if f≤ (Subscript[f, c])}, {0, if f>(Subscript[f, c])}}]) ,

the first integral is easy to evaluate analytically and one obtains the following expression for the autocorrelation function:

(Subscript[R, E])(τ)=(((Subscript[E, 0])^2)/4)exp(-2 h0 (-(((sin(c π τ))^2)/(Subscript[f, c]))+π τ Si(2 (Subscript[f, c]) π τ))),

where Si(z) is the sine integral. However, it is not possible to obtain an analytical expression for the Fourier transform of this expression. Therefore, the laser lineshape (Subscript[S, E])(ν-(Subscript[ν, 0])) is evaluated numerically using the discrete Fourier transform.

The red line, separating the frequency noise spectrum into two regions in which the effect of noise on the lineshape is radically different, can be determined by studying the asymptotic behavior of the two limiting cases (Subscript[f, c]) ≪ (Subscript[h, 0]) and (Subscript[f, c]) ≫ (Subscript[h, 0]). It is given by the following equation:

(Subscript[S, δν])=((8 log(2))/(π^2))f.

The calculation of the laser lineshape (Subscript[S, E])(ν-(Subscript[ν, 0])) from the frequency noise spectral density (Subscript[S, δν])(f) is described in D. S. Elliott, R. Roy, and S. J. Smith, "Extracavity Laser Band-Shape and Bandwidth Modification," Phys. Rev. A 26, 1982 pp. 12–18. First, one calculates the autocorrelation function of the optical field:

(Subscript[R, E])(τ)=(OverBar[E(t)(SuperStar[E])(t+τ)])=(((Subscript[E, 0])^2)/4)exp(-2(∫_0^∞)(Subscript[S, δν])[f](((sin(π f τ))^2)/(f^2))df).

Then the lineshape is given by the Fourier transform of the autocorrelation function:

(Subscript[S, E])(ν-(Subscript[ν, 0]))=(∫_0^∞)cos(2π(ν-(Subscript[ν, 0]))τ) (Subscript[R, E])(τ)dτ.

In the case of a low-pass filtered white noise, that is, for a frequency noise spectral density given by

(Subscript[S, δν])(f)=(Piecewise[{{(Subscript[h, 0]), if f≤ (Subscript[f, c])}, {0, if f>(Subscript[f, c])}}]) ,

the first integral is easy to evaluate analytically and one obtains the following expression for the autocorrelation function:

(Subscript[R, E])(τ)=(((Subscript[E, 0])^2)/4)exp(-2 h0 (-(((sin(c π τ))^2)/(Subscript[f, c]))+π τ Si(2 (Subscript[f, c]) π τ))),

where Si(z) is the sine integral. However, it is not possible to obtain an analytical expression for the Fourier transform of this expression. Therefore, the laser lineshape (Subscript[S, E])(ν-(Subscript[ν, 0])) is evaluated numerically using the discrete Fourier transform.

The red line, separating the frequency noise spectrum into two regions in which the effect of noise on the lineshape is radically different, can be determined by studying the asymptotic behavior of the two limiting cases (Subscript[f, c]) ≪ (Subscript[h, 0]) and (Subscript[f, c]) ≫ (Subscript[h, 0]). It is given by the following equation:

(Subscript[S, δν])=((8 log(2))/(π^2))f.

THIS NOTEBOOK IS THE SOURCE CODE FROM

"Laser Lineshape and Frequency Fluctuations: Low-Pass Filtered White Noise" from The Wolfram Demonstrations Project
 http://demonstrations.wolfram.com/LaserLineshapeAndFrequencyFluctuationsLowPassFilteredWhiteNo/

Contributed by: Gianni Di Domenico (Université de Neuchâtel)

A full-function Wolfram Mathematica system (Version 6 or higher) is required to edit this notebook.
GET WOLFRAM MATHEMATICA »

© The Wolfram Demonstrations Project & Contributors   |   Terms of Use   |   Make a new version of this Demonstration »