Multiple Slit Diffraction Pattern

Manipulate[
Plot[{((1/n)ChebyshevU[n-1,Cos[b k/2]]Sinc[a k/2])^2,Sinc[a k/2]^2},{k,-kmax,kmax},
PlotRange->{0,1},
Axes->False,
Frame->True,
FrameTicks->{True,False},
FrameLabel->{"position","intensity"},
PlotLabel->ToString[n]<>" slit diffraction pattern",
Filling->{1->Axis},
PlotStyle->{Automatic,{Thick,Dashed}},
ImageSize->{500,350},
ImagePadding->{{40,20},{40,20}}],
{{a,0.5,"slit width"},0,1,Appearance->"Labeled"},
{{b,2.5,"slit spacing"},1,5,Appearance->"Labeled"},
{{n,2,"number of slits"},Range[10],SetterBar},
Delimiter,
{{kmax,10,"horizontal range"},1,100,Appearance->"Labeled"}]

In this Demonstration we visualize the diffraction pattern of n equally spaced slits of equal width, also known as a diffraction grating. It can be shown that the diffraction pattern is equivalent to the diffraction pattern for n delta function slits modulated by the diffraction pattern of a single slit of finite width. The latter thus acts as an envelope, shown by the thick dashed line. Special cases of this system include the single (n=1) and double (n=2) slits, which appear in introductory physics courses. The horizontal scale is arbitrary and the vertical scale normalized to the peak intensity.

For an array of n slits of width a and equal spacing d, the intensity of the diffracted light on a screen may be neatly expressed as

(I/(Subscript[I, 0]))=((((1/n)(Subscript[U, n-1])(cos(((d q)/2)))sinc(((a q)/2))))^2),

where (Subscript[I, 0]) is the peak intensity and (Subscript[U, n])(x) is the Chebyshev polynomial of the second kind, which appears when we simplify the ratio sin(n x)/sin(x).

The parameter q is a normalized wavenumber. It is related to the actual wavenumber k, the perpendicular distance R from the diffraction grating to the screen on which the pattern is observed, and the distance from the center of the pattern x, by q=((k x)/R).

The formula for the intensity is valid within the Fraunhofer diffraction regime, for which R≫a,d. In this case, the diffraction pattern is equivalent to the Fourier transform of the diffraction grating. This explains why, since an array of finite-width slits is equivalent to the convolution of an array of delta function slits with a single slit, the resulting diffraction pattern is the product of the two corresponding diffraction patterns.

Snapshot 1: for a single, infinitely narrow slit, the diffraction pattern is constant; this is essentially because the Fourier transform of the delta function is constant

Snapshot 2: for multiple infinitely narrow slits, there is an infinitely repeating pattern of peaks and troughs, corresponding to constructive/destructive interference between paths from different slits

Snapshot 3: for a single slit of finite width, the diffraction pattern has the well-known form of a sinc function

Snapshot 4: for multiple slits of finite width, the diffraction is a pattern of peaks and troughs modulated by the sinc function pattern arising from the finite width of each slit

Contributed by: Peter Falloon