Dispersion of Light through a Prism

Manipulate[
Graphics[{
Line[{{-1,-(Sqrt[3])},{0,0},{1,-(Sqrt[3])},{-1,-(Sqrt[3])}}],Thick,White,
Rotate[Line[{{-4,-(Sqrt[3])/2},{-1/2,-(Sqrt[3])/2}}],(θ-30)°,{-1/2,-(Sqrt[3])/2}],
Table[{color[[k]],Line[{{-1/2,-(Sqrt[3])/2},{x[k,θ],-(Sqrt[3])x[k,θ]},
{2.5,-Tan[Θ[k,θ]]x[k,θ]-((Sqrt[3])+Tan[Θ[k,θ]-π/6])x[k,θ]}}]},{k,1,7}]},
ImageSize->{575,475},PlotRange -> {{-1.5,2.5},{.5,-2(Sqrt[3])}},Background->LightGray],
{{θ,60,"prism incidence angle (deg)"},40 ,80 ,1 ,Appearance -> "Labeled"},TrackedSymbols:>{θ},ControlPlacement->Top,
Initialization:>(color={Magenta,Lighter[Blue],Blue,Green, Yellow, Orange, Red};n[k_]:=1.6-.02k;m[k_,θ_]:=Tan[-π/6+ArcSin[Sin[θ °]/n[k]]];x[k_,θ_]:=(1/2)((((Sqrt[3])-m[k,θ])/((Sqrt[3])+m[k,θ])));
Θ[k_,θ_]:=ArcSin[n[k]Sin[π/3-ArcSin[Sin[θ °]/n[k]]]];)]

CAPTION

This Demonstration shows the dispersion of white light through a prism as the incidence angle is varied.

When a light ray passes from one medium to another at an angle, it refracts (or bends). The refraction of light at the interface is governed by Snell's law. White light is a combination of different colors in the visible spectrum, and different colors have different indexes of refraction. Thus, when the ray of white light passes through a prism, the colors refract at different angles. The frequency variation of the index of refraction has been slightly exaggerated for better graphic representation.

Borosilicate optical glass has an index of refraction varying between 1.51 to 1.53 in the visible range.

THIS NOTEBOOK IS THE SOURCE CODE FROM

Siva Perla

"Dispersion of Light through a Prism"
 http://demonstrations.wolfram.com/DispersionOfLightThroughAPrism/
 Wolfram Demonstrations Project
 Published: August 3, 2007

A full-function Wolfram Mathematica system is required to edit this notebook.
GET WOLFRAM MATHEMATICA »

© Wolfram Demonstrations Project & Contributors   |   Terms of Use   |   Make a new version of this Demonstration »