Earlier we saw how to use Framed to add a frame when one displays something.

Framed[2^100]

You can give options to Framed.

Framed[2^100,Background->LightYellow,FrameStyle->LightGray]

Labeled lets you make things be labeled.

Labeled[Framed[2^100],"a big number"]

Labeled[Style[2^100,Background->Yellow],"a big number"]

Labeled[Style[2^100,Background->Yellow],Style["a big number",Italic,Orange]]

You can use Labeled in graphics as well.

PieChart[{Labeled[1,"one"],Labeled[2,"two"],Labeled[3,Red],Labeled[4,Orange],2,2}]

ListPlot[{Labeled[1,"one"],Labeled[2,"two"],Labeled[3,Pink],Labeled[4,Yellow],5,6,7}]

ListPlot[Table[Labeled[Prime[n],Prime[n]],{n,15}]]

Labeled indicates something by putting a label right next to it. It’s often nice instead to use “callouts”, that have little lines pointing to whatever they’re referring to. You can do this by using Callout rather than Labeled.

ListPlot[Table[Callout[Prime[n],Prime[n]],{n,15}]]

There are all sorts of ways to annotate graphics. Style directly inserts styling. Tooltip generates interactive tooltips that show themselves when the mouse hovers over them. Legended puts labels into a legend on the side.

PieChart[{Style[3,Red],Style[2,Green],Style[1,Yellow],1,2}]

PieChart[{Legended[1,"one"],Legended[2,"two"],Legended[3,Pink],Legended[4,Yellow],2,2}]

PieChart[{1,2,3,4,2,2},PlotTheme->"Web"]

If you want the Wolfram Language to just automatically pick how to annotate things, then simply give the annotations with rules (->).

ListPlot[{1->"one",2->"two",3->Pink,4->Yellow,5,6,7}]

PieChart[{1->"one",2->"two",3->Blue,4->Red}]

It’s common to want to combine different objects for presentation. Row, Column and Grid are convenient ways to do this.

Row[{Yellow,Pink,Cyan}]

Column[{Yellow,Pink,Cyan}]

Use GraphicsRow, GraphicsColumn and GraphicsGrid to arrange objects to fit in a certain overall size.

GraphicsGrid[Table[PieChart[RandomReal[10,5]],3,6]]

GraphicsGrid[Table[PieChart[RandomReal[10,5]],3,6],Frame->All]

Make a list of numbers up to 100, with even numbers on yellow and odd numbers on light gray. »

Make a list of numbers up to 100, with primes framed. »

Make a list of numbers up to 100, with primes framed and labeled in light gray with their values modulo 4. »

Create a 3×6 GraphicsGrid of randomly colored disks. »

Make a pie chart of the GDPs of the countries in the G5, labeling each wedge. »

Make a pie chart of the populations of the countries in the G5, giving a legend for each wedge. »

Make a 5×5 GraphicsGrid of pie charts that give the relative frequencies of digits in 2^n with n starting at 1. »

Make a graphics row of word clouds for Wikipedia articles on the G5 countries. »

Can I get rounded corners with Framed?

Yes. Use an option like RoundingRadius->0.2.

What kinds of things can be in a label?

Anything you want. A label can be text or a graphic or, for that matter, a whole notebook.

Can I use Labeled to put labels in places other than at the bottom?

Yes. Use e.g. Labeled[expr,label,Left] or Labeled[expr,label,Right].

How do I determine where a legend goes?

Use Placed.

Can visualization be animated or dynamic?

Yes. ListAnimate creates an animation. Constructs from Tooltip to Manipulate can be used to set up dynamic visualizations.

Tech Notes