We saw earlier how to use (Key1[ctrl, =]) to enter natural language input. Now we’re going to talk about how to set up functions that understand natural language.

Interpreter is the key to much of this. You tell Interpreter what type of thing you want to get, and it will take any string you provide, and try to interpret it that way.

Interpreter["City"]["nyc"]

Interpreter["City"]["the big apple"]

Interpreter["Color"]["hot pink"]

Interpreter converts natural language to Wolfram Language expressions that you can compute with. Here’s an example involving currency amounts.

Interpreter["CurrencyAmount"][{"4.25 dollars","34 russian rubles","5 euros","85 cents"}]

Total[{(QuantityPrefix[4.25, "$" , US dollars, "USDollars"]),(QuantityPrefix[34, " руб" , Russian rubles, "RussianRubles"]),(QuantityPrefix[5, "€" , euros, "Euros"]),(QuantityPostfix[85,  "¢", US cents, "USCents"])}]

Here’s another example, involving locations.

Interpreter["Location"]["White House"]

Interpreter["Location"]["1600 Pennsylvania Avenue, Washington, DC"]

Interpreter handles many hundreds of different types of objects.

Interpreter["University"][{"Harvard","Stanford","U of I"}]

Interpreter["Chemical"][{"H2O","aspirin","CO2","wolfram"}]

EntityValue[Interpreter["Animal"][{"cheetah","tiger","elephant"}],"Image"]

{,,}

Interpreter interprets whole strings. TextCases, on the other hand, tries to pick out instances of what you request from a string.

TextCases["A sentence is a linguistic construct","Noun"]

TextCases["Choose between $5, €5 and ¥5000","CurrencyAmount"]

You can use TextCases to pick out particular kinds of things from a piece of text. Here we pick out instances of country names in a Wikipedia article.

WordCloud[TextCases[WikipediaData["EU"],"Country"]]

TextStructure shows you the whole structure of a piece of text.

TextStructure["You can do so much with the Wolfram Language."]

TextStructure["You can do so much with the Wolfram Language.","ConstituentGraphs"]

WordList[ ] gives a lists of common words. WordList["Noun"], etc. gives lists of words that can be used as particular parts of speech.

Take[WordList["Verb"],20]

It’s easy to study properties of words. Here are histograms comparing the length distributions of nouns, verbs and adjectives in the list of common words.

Histogram[StringLength[WordList[#]]]&/@{"Noun","Verb","Adjective"}

So far we’ve only talked about English. But the Wolfram Language also knows about other languages. For example, WordTranslation gives translations of words.

WordTranslation["hello","French"]

WordTranslation["hello","Korean"]

Transliterate[WordTranslation["hello","Korean"]]

If you want to compare lots of different languages, give All as the language for  WordTranslation. The result is an association which gives translations for different languages, with the languages listed roughly in order of decreasing worldwide usage.

Take[WordTranslation["hello",All],5]

Let’s take the top 100 languages, and look at the first character in the first translation for “hello” that appears. Here’s a word cloud that shows that among these languages, “h” is the most common letter to start the word for “hello”.

WordCloud[Values[StringTake[First[#],1]&/@Take[WordTranslation["hello",All],100]]]

Use Interpreter to find the location of the Eiffel Tower. »

Use Interpreter to find a university referred to as “U of T”. »

Use Interpreter to find the chemicals referred to as C2H4, C2H6 and C3H8. »

Use Interpreter to interpret the date “20140108”. »

Find universities that can be referred to as “U of X”, where x is any letter of the alphabet. »

Find which US state capital names can be interpreted as movie titles (use CommonName to get the string versions of entity names). »

Find cities that can be referred to by permutations of the letters a, i, l and m. »

Make a word cloud of country names in the Wikipedia article on “gunpowder”. »

Find all nouns in “She sells seashells by the sea shore.” »

Use TextCases to find the number of nouns, verbs and adjectives in the first 1000 characters of the Wikipedia article on computers. »

Find the grammatical structure of the first sentence of the Wikipedia article about computers. »

Find the 10 most common nouns in ExampleData[{"Text","AliceInWonderland"}]. »

Make a community graph plot of the graph representation of the text structure of the first sentence of the Wikipedia article about language. »

Make a list of numbers of nouns, verbs, adjectives and adverbs found by WordList in English. »

Generate a list of the translations of numbers 2 through 10 into French. »

What possible types of interpreters are there?

It’s a long list. Check out the documentation, or evaluate $InterpreterTypes to see the list.

Does Interpreter need a network connection?

In simple cases, such as dates or basic currency, no. But for full natural language input, yes.

When I say “4 dollars”, how does it know if I want US dollars or something else?

It uses what it knows of your geo location to tell what kind of dollars you’re likely to mean.

Can Interpreter deal with arbitrary natural language?

If something can be expressed in the Wolfram Language, then Interpreter should be able to interpret it. Interpreter["SemanticExpression"] takes any input, and tries to understand its meaning so as to get a Wolfram Language expression that captures it. What it’s doing is essentially the first stage of what Wolfram|Alpha does.

Can I add my own interpreters?

Yes. GrammarRules lets you build up your own grammar, making use of whatever existing interpreters you want.

Can I find the meaning of a word?

WordDefinition gives dictionary definitions.

Can I find what part of speech a word is?

PartOfSpeech tells you all the parts of speech a word can correspond to. So for “fish” it gives noun and verb. Which of these is correct in a given case depends on how the word is used in a sentence—and that’s what TextStructure figures out.

Can I translate whole sentences as well as words?

TextTranslation does this for some languages, usually by calling an external service.

What languages does WordTranslation handle?

It can translate lots of words for the few hundred most common languages. It can translate at least a few words for well over a thousand languages. LanguageData gives information on over 10,000 languages.

Tech Notes