When you do a computation with whole numbers, the Wolfram Language gives you an exact answer. It does the same with exact fractions.

1/2+1/3

Often you’ll just want a numerical or decimal approximation. You can get that using the function N (for “numerical”).

N[1/2+1/3]

If there’s any decimal number in your input, the Wolfram Language will automatically give you an approximate answer.

1.8/2+1/3

1/2.+1/3

The Wolfram Language can handle numbers of any size, at least so long as they fit in your computer’s memory.

2^1000

N[2^1000]

This approximate form is given in scientific notation. If you need to enter scientific notation, you can do it with *^.

2.7*^6

Commonly used numbers like π (pi) are built into the Wolfram Language.

N[Pi]

The Wolfram Language can compute to arbitrary precision, so for example it can find millions of digits of π if you want them.

N[Pi,250]

There are many functions in the Wolfram Language that handle integers (whole numbers). There are also many functions that handle real numbers—approximate numbers with decimals. An example is RandomReal, which gives random real numbers.

RandomReal[10]

Table[RandomReal[10],5]

RandomReal[10,5]

RandomReal[{20,30},5]

The Wolfram Language has a huge range of mathematical functions built in, from basic to very sophisticated.

Prime[100]

Prime[1000000]

ListPlot[Table[Prime[n],{n,50}]]

Three functions common in many practical situations are Sqrt (square root), Log10 (logarithm to base 10) and Log (natural logarithm).

Sqrt[16]

Sqrt[200]

N[Sqrt[200]]

Logarithms are often useful when you’re dealing with numbers that have a wide range of sizes. Let’s plot the masses of the planets. With ListPlot one can’t tell anything about the planets before Jupiter. But ListLogPlot shows the relative sizes much more clearly.

ListPlot[(EntityClass["planets", EntityClass["Planet",All], "EntityClass[\"Planet\", All]", "planets"])["Mass"]]

ListLogPlot[(EntityClass["planets", EntityClass["Planet",All], "EntityClass[\"Planet\", All]", "planets"])["Mass"]]

There are a few more functions that show up frequently in general programming. First, there’s the almost trivial function Abs, that finds the absolute value, or positive part, of a number.

{Abs[3],Abs[-3]}

Next there’s Round, which rounds to the nearest whole number.

{Round[3.2],Round[3.4],Round[3.6],Round[3.9]}

Another function that’s very useful is Mod. Let’s say you’re counting up minutes in an hour. When you reach 60, you’ll want to start again from 0. That’s what Mod lets you do.

{Mod[50,60],Mod[55,60],Mod[60,60],Mod[65,60],Mod[70,60]}

Find (Sqrt[2]) to 500-digit precision. »

Generate 10 random real numbers between 0 and 1. »

Make a plot of 200 points with random real x and y coordinates between 0 and 1. »

Create a random walk using AnglePath and 1000 random real numbers between 0 and 2π. »

Make a table of Mod[n^2,10] for n from 0 to 30. »

Make a line plot of Mod[n^n,10] for n from 1 to 100. »

Make a table of the first 10 powers of π, rounded to integers. »

Make a graph by connecting n with Mod[n^2,100] for n from 0 to 99. »

Generate graphics of 50 circles with random real coordinates 0 to 10, random real radii from 0 to 2, and random colors. »

Make a plot of the nth prime divided by n*log(n), for n from 2 to 1000. »

Make a line plot of the differences between successive primes up to 100. »

Generate a sequence of 20 middle C notes with random durations between 0 and 0.5 seconds. »

Make an array plot of Mod[i,j] for i and j up to 50. »

Make a list for n from 2 to 10 of array plots for x and y up to 50 of x^y mod n. »

Use Round to compute the fractional part of π to 50 digits. »

Find the sum of the first 1000 prime numbers. »

Make a list of the first 100 primes modulo 4. »

Make a list of the first 10000 primes modulo 4, multiply them by 90° and create an angle path from them. »

What are examples of mathematical functions in the Wolfram Language?

From standard school math, ones like Sin, Cos, ArcTan, Exp, as well as GCD, Factorial, Fibonacci. From physics and engineering and higher math, ones like Gamma (“gamma function”), BesselJ (“Bessel function”), EllipticK (“elliptic integral”), Zeta (“Riemann zeta function”), PrimePi, EulerPhi. From statistics, ones like Erf, NormalDistribution, ChiSquareDistribution. Hundreds of functions altogether.

What is the precision of a number?

It’s the total number of decimal digits quoted in the number. N[100/3,5] gives 33.333, which has 5 digits of precision. The number 100/3 is exact; N[100/3,5] approximates it to 5-digit precision.

What does the  at the end of each line in a long number mean?

It’s there to show that the number continues onto the next line—like a hyphen in text.

Can I work with numbers in bases other than 10?

Yes. Enter a number in base 16 as 16^^ffa5. Find digits using IntegerDigits[655,16].

Can the Wolfram Language handle complex numbers?

Of course. The symbol I (capital “i”) represents the square root of −1.

Why does N[1.5/7,100] not give me a 100-digit result?

Because 1.5 is an approximate number with much less than 100-digit precision. N[15/70,100] will for example give a 100-digit-precision number.

Tech Notes